Made by SteveAndrew 6.1

How to use this cheat table? Install Cheat Engine; Double-click the.CT file in order to open it. Click the PC icon in Cheat Engine in order to select the game process. Activate the trainer options by checking boxes or setting values from 0 to 1. Our Resident Evil 4 HD +7 trainer is now available for version 1.0.6 DE and supports STEAM. These Resident Evil 4 HD cheats are designed to enhance your experience with the game.

EDIT: I fixed the Button Masher! I was missing one more address... after further testing, I found that some zombies it wasn't instant button mashing! So I found the third address, now hopefully it covers everything. Two conditional jumps are nopped now, and one address is hooked to change the value of a float (that also could be a conditional jump change but I was having trouble finding which one to change into an unconditional or nop for that particular button mash, so I just forced the value instead which will cause the proper route to be taken Wink) Also made l0wb1t's no recoil script into aobscan, and optimized it to my liking! (xorps on the xmm1 register [to zero it] and moving that into the recoil memory location rather than directly moving zero into the memory location, then copying that into xmm1)
Others have posted similar Auto Assembler scripts, though I've done mine a bit differently, and they are all aobscan Wink Cheat Engine 6.1 For Resident Evil 4

Features:
*Pro Infinite Health (For you and buddy) [hooks write address only]
*One Hit Kill
*Infinite Ammo /w No Reload + Infinite All Usable Items (Just have at least one to use infinite [one bullet, one grenade, etc...])
Separate version to safetly use with Leon (because of duel wield WingShooters)
Infinite Skill Points (hooks two addresses to make sure it will work, just have enough to buy 1 skill and you'll have enough to buy all skills after you buy a single one)
*JUST ADDED: Auto Button Masher - enable this to not have to mash any buttons for any instance the game might have you button mash (that I'm aware of) Opening boxes, getting zombies off of you, lowering bridges, flipping switches, etc...
*JUST ADDED: Mercenaries mode freeze timer, use CE configured hotkeys F12 to toggle on/off and F11 to add 5 seconds to the clock [may have to disable/enable with f12 to see the new time if you add time that way]
*JUST ADDED: No Recoil - FULL CREDIT TO: l0wb1t I borrowed it from his CT, I don't think he will mind! Very Happy (forgot to make it an aobscan script though, will do that in the next update)
*Player Teleport Fly - Upon enabling go in game and press WSAD keys to move around relative to map, and left shift + left control to move up and down... F1 to toggle it on /off while in game to not have to keep truly enabling/disabling it (I like how you slowly glide down if you put yourself in the air, that's just how it is... Also you don't lose accuracy while being in the air like other games Very Happy, I guess you were never really meant to be in the air) Right now it included you and you're companion in it, looking for a way to separate the two so it only effects you!
*Zombie Vac - Upon enabling go in game and all Zombies will be sucked to your position (sometimes your companions instead) and they will stay there, use the arrow keys to move the vac around, and right control to move it up, right alt to move it down. F2 while in game to toggle on/off [useful for changing the vac position quickly to your characters position / sometimes your companion's]
Video of Zombie Vac and Player Teleport Fly here:
[Link]
Screenshot of Zombie Vac: (Looks cooler with more zombies but just snapped a quick picture lol)
To use, just enable which options you want on the CT, change 'One Hit Kill' on the CT to 1 after enabling infinite health for one hit kills!
Get CT at the bottom of this post!
More coming soon Very Happy
Zombie Vac Very Happy hehehe
Code:
[enable]
alloc(ZombieVac,256)
alloc(KeyHandlerThread,256)
aobscan(ZombieVacAddress,f3 0f 11 4c 24 14 f3 0f 11 54 24 ? f3 0f 11 00 f3 0f 10 44 24)
label(ZombieVacAddy)
label(ZombieVacEnabled)
label(CurrentVacCoords)
label(VacMoveSpeed)
label(GetCoordsFirst)
label(ZombieVacFullyDisabled)
label(ExitKeyHandler)
label(ToggleOnOff)
label(TestKeyAndIncreaseDecreaseIfNeeded)
label(NotPressed)
label(IncreaseIt)
createthread(KeyHandlerThread)
registersymbol(ZombieVacAddy)
registersymbol(ZombieVacFullyDisabled)
registersymbol(VacMoveSpeed)
ZombieVac:
movss [eax],xmm0
movss xmm0,[esp+14]
cmp [ZombieVacEnabled],1
jne ZombieVacAddy+0a
cmp [CurrentVacCoords],0
je GetCoordsFirst
cmp [eax-18],1 //Don't vac player
jne ZombieVacAddy+0a
movss xmm0,[CurrentVacCoords] //X
movss [eax],xmm0
movss xmm0,[CurrentVacCoords+4] //Z
movss [eax+4],xmm0
movss xmm0,[CurrentVacCoords+8] //Y
movss [eax+8],xmm0
jmp ZombieVacAddy+1a
GetCoordsFirst:
cmp [eax-18],1
je ZombieVacAddy+0a
//Use player coords as vac starting position
movss xmm0,[eax]
movss [CurrentVacCoords],xmm0
movss xmm0,[eax+4]
movss [CurrentVacCoords+4],xmm0
movss xmm0,[eax+8]
movss [CurrentVacCoords+8],xmm0
jmp ZombieVacAddy+1a
KeyHandlerThread:
push 0a
call Sleep
cmp [ZombieVacFullyDisabled],1
je ExitKeyHandler
push 71 //F2
call GetAsyncKeyState
test ax,ax
jne ToggleOnOff
cmp [ZombieVacEnabled],1
jne KeyHandlerThread
push CurrentVacCoords //X
push 1 //increase it if key is down
push 27 //Key: 'D'
call TestKeyAndIncreaseDecreaseIfNeeded
push CurrentVacCoords //X
push 0 //decrease it if key is down
push 25 //Key: 'A'
call TestKeyAndIncreaseDecreaseIfNeeded
push CurrentVacCoords+8 //Y
push 1
push 26
call TestKeyAndIncreaseDecreaseIfNeeded
push CurrentVacCoords+8 //Y
push 0
push 28
call TestKeyAndIncreaseDecreaseIfNeeded
push CurrentVacCoords+4 //Z
push 1
push a3 //Key: 'right control'
call TestKeyAndIncreaseDecreaseIfNeeded
push CurrentVacCoords+4 //Z
push 0
push a5 //Key: 'right alt'
call TestKeyAndIncreaseDecreaseIfNeeded
jmp KeyHandlerThread
ToggleOnOff:
xor eax,eax
mov [CurrentVacCoords],eax
xor [ZombieVacEnabled],1
push 96
call Sleep
jmp KeyHandlerThread
ExitKeyHandler:
ret
//void __stdcall TestKeyAndIncDec(int Key, bool IncOrDec, float *pFloatValue)
TestKeyAndIncreaseDecreaseIfNeeded:
push [esp+4] //Key
call GetAsyncKeyState
test ax,ax
je NotPressed
mov eax,[esp+0c] //Address of the coordinate
fld dword ptr [eax]
cmp [esp+8],1 //Increase or decrease it?
je IncreaseIt
fsub dword ptr [VacMoveSpeed]
fstp dword ptr [eax]
jmp NotPressed
IncreaseIt:
fadd dword ptr [VacMoveSpeed]
fstp dword ptr [eax]
NotPressed:
ret 0c
ZombieVacEnabled:
dd 1
ZombieVacFullyDisabled:
dd 0
VacMoveSpeed:
dd (float)5.0
CurrentVacCoords:
dd 0 0 0
ZombieVacAddress+0c:
ZombieVacAddy:
jmp ZombieVac
db 90 90 90 90 90
[disable]
ZombieVacAddy:
db f3 0f 11 00 f3 0f 10 44 24 14
//movss [eax],xmm0
//movss xmm0,[esp+14]
ZombieVacFullyDisabled:
dd 1
dealloc(ZombieVac)
unregistersymbol(ZombieVacAddy)
unregistersymbol(ZombieVacFullyDisabled)
unregistersymbol(VacMoveSpeed)
Infinite Health + One Hit Kill: (EDIT: simplified script, but it works the same Wink)
Code:
//Resident Evil 6
//Infinite Health
//Steve Andrew
[enable]
alloc(InfiniteHealth,64)
aobscan(HealthAddress,66 8b 44 24 04 66 29 81 10 0f 00 00 79)
label(HealthAddy)
label(OneHitKill)
label(HealthRet)
registersymbol(HealthAddy)
registersymbol(OneHitKill)
InfiniteHealth:
cmp [ecx+38],1
jne HealthRet+0b //Skips decreasing health for player
//kills enemies in one hit
cmp [OneHitKill],1
je HealthRet+2
//decreases enemy health normally
sub [ecx+f10],ax
jmp HealthRet
OneHitKill: